AES data .sys works now
[gnuk/gnuk.git] / src / gnuk.ld.in
1 /*
2     ChibiOS/RT - Copyright (C) 2006,2007,2008,2009,2010 Giovanni Di Sirio.
3
4     This file is part of ChibiOS/RT.
5
6     ChibiOS/RT is free software; you can redistribute it and/or modify
7     it under the terms of the GNU General Public License as published by
8     the Free Software Foundation; either version 3 of the License, or
9     (at your option) any later version.
10
11     ChibiOS/RT is distributed in the hope that it will be useful,
12     but WITHOUT ANY WARRANTY; without even the implied warranty of
13     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14     GNU General Public License for more details.
15
16     You should have received a copy of the GNU General Public License
17     along with this program. If not, see <http://www.gnu.org/licenses/>.
18
19                                       ---
20
21     A special exception to the GPL can be applied should you wish to distribute
22     a combined work that includes ChibiOS/RT, without being obliged to provide
23     the source code for any proprietary components. See the file exception.txt
24     for full details of how and when the exception can be applied.
25 */
26
27 /*
28  * ST32F103 memory setup.
29  */
30 __main_stack_size__     = 0x0400;
31 __process_stack_size__  = 0x0200;
32 __stacks_total_size__   = __main_stack_size__ + __process_stack_size__;
33
34 MEMORY
35 {
36     flash0 : org = @ORIGIN@, len = 4k
37     flash  : org = @ORIGIN@+0x1000, len = @FLASH_SIZE@k - 4k
38     ram : org = 0x20000000, len = 20k
39 }
40
41 __flash_start__         = ORIGIN(flash);
42 __flash_end__           = ORIGIN(flash) + LENGTH(flash);
43
44 __ram_start__           = ORIGIN(ram);
45 __ram_size__            = LENGTH(ram);
46 __ram_end__             = __ram_start__ + __ram_size__;
47
48 SECTIONS
49 {
50     . = 0;
51
52     .sys : ALIGN(16) SUBALIGN(16)
53     {
54         KEEP(*(.vectors))
55         sys.o(.text)
56         sys.o(.text.*)
57         sys.o(.rodata)
58         sys.o(.rodata.*)
59         . = ALIGN(1024);
60         *(.sys)
61     } > flash0
62
63     .text : ALIGN(16) SUBALIGN(16)
64     {
65         _text = .;
66         KEEP(*(vectors))
67         *(.text)
68         *(.text.*)
69         *(.rodata)
70         *(.rodata.*)
71         *(.glue_7t)
72         *(.glue_7)
73         *(.gcc*)
74     } > flash
75
76     .ctors :
77     {
78         PROVIDE(_ctors_start_ = .);
79         KEEP(*(SORT(.ctors.*)))
80         KEEP(*(.ctors))
81         PROVIDE(_ctors_end_ = .);
82     } > flash
83
84     .dtors :
85     {
86         PROVIDE(_dtors_start_ = .);
87         KEEP(*(SORT(.dtors.*)))
88         KEEP(*(.dtors))
89         PROVIDE(_dtors_end_ = .);
90     } > flash
91
92     .ARM.extab : {*(.ARM.extab* .gnu.linkonce.armextab.*)}
93
94     __exidx_start = .;
95     .ARM.exidx : {*(.ARM.exidx* .gnu.linkonce.armexidx.*)} > flash
96     __exidx_end = .;
97
98     .eh_frame_hdr : {*(.eh_frame_hdr)}
99
100     .eh_frame : ONLY_IF_RO {*(.eh_frame)}
101
102     . = ALIGN(4);
103     _etext = .;
104     _textdata = _etext;
105
106     .data :
107     {
108         _data = .;
109         *(.data)
110         . = ALIGN(4);
111         *(.data.*)
112         . = ALIGN(4);
113         *(.ramtext)
114         . = ALIGN(4);
115         _edata = .;
116     } > ram AT > flash
117
118     .bss :
119     {
120         _bss_start = .;
121         *(.bss)
122         . = ALIGN(4);
123         *(.bss.*)
124         . = ALIGN(4);
125         *(COMMON)
126         . = ALIGN(4);
127         _bss_end = .;
128     } > ram
129
130     PROVIDE(end = .);
131     _end            = .;
132     . = ALIGN(512);
133     _regnual_start = .;
134
135 @CERTDO_SUPPORT_START@
136     .gnuk_ch_certificate :
137     {
138         . = ALIGN (@FLASH_PAGE_SIZE@);
139         ch_certificate_start = .;
140         LONG(0xffffffff);
141         . += 1920;
142         . = ALIGN (@FLASH_PAGE_SIZE@);
143     } > flash =0xffffffff
144 @CERTDO_SUPPORT_END@
145
146     .gnuk_flash :
147     {
148         . = ALIGN (@FLASH_PAGE_SIZE@);
149         _data_pool = .;
150         KEEP(*(.gnuk_data))
151         . = ALIGN(@FLASH_PAGE_SIZE@);
152         . += @FLASH_PAGE_SIZE@;
153         _keystore_pool = .;
154         . += 512*3;
155         . = ALIGN(@FLASH_PAGE_SIZE@);
156     } > flash =0xffffffff
157 }
158
159 __heap_base__   = _end;
160 __heap_end__    = __ram_end__ - __stacks_total_size__;