Implement GC for data pool in flash memory.
[gnuk/gnuk.git] / src / gnuk.ld.in
1 /*
2     ChibiOS/RT - Copyright (C) 2006,2007,2008,2009,2010 Giovanni Di Sirio.
3
4     This file is part of ChibiOS/RT.
5
6     ChibiOS/RT is free software; you can redistribute it and/or modify
7     it under the terms of the GNU General Public License as published by
8     the Free Software Foundation; either version 3 of the License, or
9     (at your option) any later version.
10
11     ChibiOS/RT is distributed in the hope that it will be useful,
12     but WITHOUT ANY WARRANTY; without even the implied warranty of
13     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14     GNU General Public License for more details.
15
16     You should have received a copy of the GNU General Public License
17     along with this program. If not, see <http://www.gnu.org/licenses/>.
18
19                                       ---
20
21     A special exception to the GPL can be applied should you wish to distribute
22     a combined work that includes ChibiOS/RT, without being obliged to provide
23     the source code for any proprietary components. See the file exception.txt
24     for full details of how and when the exception can be applied.
25 */
26
27 /*
28  * ST32F103 memory setup.
29  */
30 __main_stack_size__     = 0x0400;
31 __stacks_total_size__   = __main_stack_size__;
32
33 MEMORY
34 {
35     flash : org = @ORIGIN@, len = @FLASH_SIZE@
36     ram : org = 0x20000000, len = 20k
37 }
38
39 __ram_start__           = ORIGIN(ram);
40 __ram_size__            = LENGTH(ram);
41 __ram_end__             = __ram_start__ + __ram_size__;
42
43 SECTIONS
44 {
45     . = 0;
46
47     .text : ALIGN(16) SUBALIGN(16)
48     {
49         _text = .;
50         KEEP(*(vectors))
51         *(.text)
52         *(.text.*)
53         *(.rodata)
54         *(.rodata.*)
55         *(.glue_7t)
56         *(.glue_7)
57         *(.gcc*)
58     } > flash
59
60     .ctors :
61     {
62         PROVIDE(_ctors_start_ = .);
63         KEEP(*(SORT(.ctors.*)))
64         KEEP(*(.ctors))
65         PROVIDE(_ctors_end_ = .);
66     } > flash
67
68     .dtors :
69     {
70         PROVIDE(_dtors_start_ = .);
71         KEEP(*(SORT(.dtors.*)))
72         KEEP(*(.dtors))
73         PROVIDE(_dtors_end_ = .);
74     } > flash
75
76     .ARM.extab : {*(.ARM.extab* .gnu.linkonce.armextab.*)}
77
78     __exidx_start = .;
79     .ARM.exidx : {*(.ARM.exidx* .gnu.linkonce.armexidx.*)} > flash
80     __exidx_end = .;
81
82     .eh_frame_hdr : {*(.eh_frame_hdr)}
83
84     .eh_frame : ONLY_IF_RO {*(.eh_frame)}
85
86     . = ALIGN(4);
87     _etext = .;
88     _textdata = _etext;
89
90     .data :
91     {
92         _data = .;
93         *(.data)
94         . = ALIGN(4);
95         *(.data.*)
96         . = ALIGN(4);
97         *(.ramtext)
98         . = ALIGN(4);
99         _edata = .;
100     } > ram AT > flash
101
102     .bss :
103     {
104         _bss_start = .;
105         *(.bss)
106         . = ALIGN(4);
107         *(.bss.*)
108         . = ALIGN(4);
109         *(COMMON)
110         . = ALIGN(4);
111         _bss_end = .;
112     } > ram
113
114     PROVIDE(end = .);
115     _end            = .;
116
117     .gnuk_random :
118     {
119         . = ALIGN (1024);
120         *(.gnuk_random)
121     } > flash =0xffffffff
122
123     .gnuk_flash : ALIGN (1024)
124     {
125         _data_pool = .;
126         KEEP(*(.gnuk_data))
127         FILL(0xffffffff);
128         . = ALIGN(1024);
129         . += 1024;
130         _keystore_pool = .;
131         FILL(0xffffffff);
132         . += 1024*3;
133     } > flash
134 }
135
136 __heap_base__   = _end;
137 __heap_end__    = __ram_end__ - __stacks_total_size__;