upgrade: gnuk side working now
[gnuk/gnuk.git] / src / gnuk.ld.in
1 /*
2     ChibiOS/RT - Copyright (C) 2006,2007,2008,2009,2010 Giovanni Di Sirio.
3
4     This file is part of ChibiOS/RT.
5
6     ChibiOS/RT is free software; you can redistribute it and/or modify
7     it under the terms of the GNU General Public License as published by
8     the Free Software Foundation; either version 3 of the License, or
9     (at your option) any later version.
10
11     ChibiOS/RT is distributed in the hope that it will be useful,
12     but WITHOUT ANY WARRANTY; without even the implied warranty of
13     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14     GNU General Public License for more details.
15
16     You should have received a copy of the GNU General Public License
17     along with this program. If not, see <http://www.gnu.org/licenses/>.
18
19                                       ---
20
21     A special exception to the GPL can be applied should you wish to distribute
22     a combined work that includes ChibiOS/RT, without being obliged to provide
23     the source code for any proprietary components. See the file exception.txt
24     for full details of how and when the exception can be applied.
25 */
26
27 /*
28  * ST32F103 memory setup.
29  */
30 __main_stack_size__     = 0x0400;
31 __process_stack_size__  = 0x0200;
32 __stacks_total_size__   = __main_stack_size__ + __process_stack_size__;
33
34 MEMORY
35 {
36     flash : org = @ORIGIN@, len = @FLASH_SIZE@k
37     ram : org = 0x20000000, len = 20k
38 }
39
40 __ram_start__           = ORIGIN(ram);
41 __ram_size__            = LENGTH(ram);
42 __ram_end__             = __ram_start__ + __ram_size__;
43
44 SECTIONS
45 {
46     . = 0;
47
48     .text : ALIGN(16) SUBALIGN(16)
49     {
50         _text = .;
51         KEEP(*(vectors))
52         *(.text)
53         *(.text.*)
54         *(.rodata)
55         *(.rodata.*)
56         *(.glue_7t)
57         *(.glue_7)
58         *(.gcc*)
59     } > flash
60
61     .ctors :
62     {
63         PROVIDE(_ctors_start_ = .);
64         KEEP(*(SORT(.ctors.*)))
65         KEEP(*(.ctors))
66         PROVIDE(_ctors_end_ = .);
67     } > flash
68
69     .dtors :
70     {
71         PROVIDE(_dtors_start_ = .);
72         KEEP(*(SORT(.dtors.*)))
73         KEEP(*(.dtors))
74         PROVIDE(_dtors_end_ = .);
75     } > flash
76
77     .ARM.extab : {*(.ARM.extab* .gnu.linkonce.armextab.*)}
78
79     __exidx_start = .;
80     .ARM.exidx : {*(.ARM.exidx* .gnu.linkonce.armexidx.*)} > flash
81     __exidx_end = .;
82
83     .eh_frame_hdr : {*(.eh_frame_hdr)}
84
85     .eh_frame : ONLY_IF_RO {*(.eh_frame)}
86
87     . = ALIGN(4);
88     _etext = .;
89     _textdata = _etext;
90
91     .data :
92     {
93         _data = .;
94         *(.data)
95         . = ALIGN(4);
96         *(.data.*)
97         . = ALIGN(4);
98         *(.ramtext)
99         . = ALIGN(4);
100         _edata = .;
101     } > ram AT > flash
102
103     .bss :
104     {
105         _bss_start = .;
106         *(.bss)
107         . = ALIGN(4);
108         *(.bss.*)
109         . = ALIGN(4);
110         *(COMMON)
111         . = ALIGN(4);
112         _bss_end = .;
113     } > ram
114
115     PROVIDE(end = .);
116     _end            = .;
117     . = ALIGN(512);
118     _regnual_start = .;
119
120 @CERTDO_SUPPORT_START@
121     .gnuk_ch_certificate :
122     {
123         . = ALIGN (@FLASH_PAGE_SIZE@);
124         ch_certificate_start = .;
125         LONG(0xffffffff);
126         . += 1920;
127         . = ALIGN (@FLASH_PAGE_SIZE@);
128     } > flash =0xffffffff
129 @CERTDO_SUPPORT_END@
130
131     .gnuk_flash :
132     {
133         . = ALIGN (@FLASH_PAGE_SIZE@);
134         _data_pool = .;
135         KEEP(*(.gnuk_data))
136         . = ALIGN(@FLASH_PAGE_SIZE@);
137         . += @FLASH_PAGE_SIZE@;
138         _keystore_pool = .;
139         . += 512*3;
140         . = ALIGN(@FLASH_PAGE_SIZE@);
141     } > flash =0xffffffff
142 }
143
144 __heap_base__   = _end;
145 __heap_end__    = __ram_end__ - __stacks_total_size__;